model modele 0 {
x~dbin(theta,5)
theta~dbeta(1,1)
}

# donnees
list(x=2)
# valeur initiale
list(theta=0.5)

*********************************
model modele 1 {

for (i in 1:40) {
x[i]~dbin(theta,n[i]) }

theta~dbeta(1,1)

}

# donnees dans basket.txt
# valeur initiale
list(theta=0.5)

**********************************

model  modele 2 {

for (i in 1:40) {
x[i]~dbin(theta[i],n[i]) 
logit(theta[i])<-c+b[i]
b[i]~dnorm(0,tau)
}


sdtheta<-sd(theta[1:40])
sigma<-1/sqrt(tau)
tau~dgamma(0.1,0.1)
c~dflat()
thetam<-exp(c)/(1+exp(c))

}

# donnees dans basket.txt
# valeurs initiales
list(tau=1,c=0,
b=c(0,0,0,0,0,0,0,0,0,0,
0,0,0,0,0,0,0,0,0,0,
0,0,0,0,0,0,0,0,0,0,
0,0,0,0,0,0,0,0,0,0
))


**************************************************
model  modele 3 {

x[1]~dbin(theta[1],n[1]) 
logit(theta[1])<-b[1]+c
b[1]~dnorm(0,tau)

for (i in 2:40) {
x[i]~dbin(theta[i],n[i]) 
logit(theta[i])<-a*(logit(theta[i-1])-c)+c+b[i]
b[i]~dnorm(0,tau)
}
sdtheta<-sd(theta[1:40])
sigma<-1/sqrt(tau)
thetam<-exp(c)/(1+exp(c))

tau~dgamma(0.1,0.1)
c~dflat()
a~dunif(-1,1)

}

# donnees du fichier basket.txt
list(n= c(5, 18, 14, 16, 18, 8, 18, 7, 6, 19, 16, 9, 10, 13, 18, 12, 
11, 19, 16, 5, 6, 12, 16, 8, 15, 17, 11, 17, 5, 11, 6, 12, 5, 
17, 13, 6, 9, 13, 18, 12),
x= c(2, 11, 8, 11, 8, 2, 9, 1, 4, 11, 8, 5, 3, 4, 8, 7, 1, 6, 9, 
3, 3, 10, 5, 5, 7, 8, 5, 6, 3, 1, 4, 5, 2, 9, 6, 1, 4, 10, 4, 
1)
)



# valeurs initiales
list(a=0.2,tau=1,c=0,
b=c(0,0,0,0,0,0,0,0,0,0,
0,0,0,0,0,0,0,0,0,0,
0,0,0,0,0,0,0,0,0,0,
0,0,0,0,0,0,0,0,0,0))